local executableName = 'newsletter-to-web';
local build_image = 'rust:1.70';

local archs = [
  { target: 'aarch64-unknown-linux-musl', short: 'arm64-musl' },
  { target: 'x86_64-pc-windows-gnu', short: 'windows' },
  { target: 'x86_64-unknown-linux-musl', short: 'amd64-musl' },
];

local getStepName(arch) = 'Build for ' + arch.short;

local builtExecutableName(arch) = executableName + if std.length(std.findSubstr(arch.short, 'windows')) > 0 then '.exe' else '';
local targetExecutableName(arch) = executableName + '-' + arch.target + if std.length(std.findSubstr(arch.short, 'windows')) > 0 then '.exe' else '';

local rustupAddTarget(arch) = 'rustup target add' + arch.target;

local add_build_steps() = [
  {
    name: getStepName(arch),
    image: build_image,
    volumes: [
      {
        name: 'dockersock',
        path: '/var/run',
      },
    ],
    commands: [
      'echo Hello World from Jsonnet on ' + arch.target + '!',
      'rustup target add ' + arch.target,
      'scripts/prepare-build.sh',
      'cargo zigbuild --release --target ' + arch.target,
      'cp target/' + arch.target + '/release/' + builtExecutableName(arch) + ' artifacts/' + targetExecutableName(arch),
      'rm -rf target/' + arch.target + '/release/*',
    ],
    depends_on: ['Prepare'],
  }
  for arch in archs
];

{
  kind: 'pipeline',
  type: 'docker',
  name: 'default',
  platform: {
    arch: 'amd64',
  },
  steps:
    [{
      name: 'Prepare',
      image: build_image,
      commands: ['scripts/prepare-build.sh'] +
                [rustupAddTarget(a) for a in archs],
    }] +
    add_build_steps() +
    [
      {
        name: 'Show built artifacts',
        image: build_image,
        commands: [
          'ls -lah artifacts',
        ],
        depends_on: [getStepName(a) for a in archs],
      },
      {
        name: 'Create release on gitea',
        image: 'plugins/gitea-release',
        settings: {
          api_key: {
            from_secret: 'gitea_token',
          },
          base_url: 'https://code.kiers.eu',
          files: 'artifacts/*',
          checksum: 'sha256',
        },
        when: {
          event: ['tag', 'promote'],
        },
        depends_on: ['Show built artifacts'],
      },
    ],

  image_pull_secrets: ['docker_private_repo'],
}